xref: /haiku/src/system/ldscripts/arm/boot_loader_efi.ld (revision 899e0ef82b5624ace2ccfa5f5a58c8ebee54aaef) 
1OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
2OUTPUT_ARCH(arm)
3ENTRY(_start)
4SECTIONS
5{
6  .text 0x0 : {
7    _text = .;
8    *(.text.head)
9    *(.text)
10    *(.text.*)
11    *(.gnu.linkonce.t.*)
12    *(.srodata)
13    *(.rodata*)
14    . = ALIGN(16);
15  }
16  _etext = .;
17  _text_size = . - _text;
18  .dynamic  : { *(.dynamic) }
19  .data :
20  {
21   __ctor_list = .;
22   *(.init_array)
23   *(.ctors)
24   __ctor_end = .;
25   _data = .;
26   *(.sdata)
27   *(.data)
28   *(.data1)
29   *(.data.*)
30   *(.got.plt)
31   *(.got)
32
33   /* the EFI loader doesn't seem to like a .bss section, so we stick
34      it all into .data: */
35   . = ALIGN(16);
36   _bss = .;
37   *(.sbss)
38   *(.scommon)
39   *(.dynbss)
40   *(.bss)
41   *(.bss.*)
42   *(COMMON)
43   . = ALIGN(16);
44   _bss_end = .;
45  }
46
47  .rel :
48  {
49   *(.rel.text) *(.rel.text*)
50   *(.rel.init_array)
51   *(.rel.fini_array)
52   *(.rel.dyn)
53   *(.rel.plt)
54   *(.rel.got)
55   *(.rel.data) *(.rel.data*)
56  }
57  _edata = .;
58  _data_size = . - _etext;
59
60  . = ALIGN(4096);
61  .dynsym   : { *(.dynsym) }
62  . = ALIGN(4096);
63  .dynstr   : { *(.dynstr) }
64  . = ALIGN(4096);
65
66  _end = . ;
67  .note.gnu.build-id : { *(.note.gnu.build-id) }
68  /DISCARD/ :
69  {
70    *(.rel.reloc)
71    *(.eh_frame)
72    *(.note.GNU-stack)
73  }
74  .comment 0 : { *(.comment) }
75}
76